noise

noise — A white noise generator with an IIR lowpass filter.

Description

A white noise generator with an IIR lowpass filter.

Syntax

ares noise xamp, kbeta

Initialization

ioffset -- the delay before the first impulse. If it is negative, the value is taken as the number of samples, otherwise it is in seconds. Default is zero.

Performance

xamp -- amplitude of final output

kbeta -- beta of the lowpass filter. Should be in the range of 0 to 1.

The filter equation is:


y_n = sqrt(1-beta^2) * x_n + beta Y_(n-1)
      

where x_n is white noise.

Examples

Here is an example of the noise opcode. It uses the file noise.csd.

Example 243. Example of the noise opcode.

See the sections Real-time Audio and Command Line Flags for more information on using command line flags.
<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
; Audio out   Audio in    No messages
-odac           -iadc     -d     ;;;RT audio I/O
; For Non-realtime ouput leave only the line below:
; -o noise.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

; Initialize the global variables.
sr = 44100
kr = 4410
ksmps = 10
nchnls = 1

; Instrument #1.
instr 1
  kamp = 30000

  ; Change the beta value linearly from 0 to 1.
  kbeta line 0, p3, 1

  a1 noise kamp, kbeta
  out a1
endin


</CsInstruments>
<CsScore>

; Play Instrument #1 for one second.
i 1 0 1
e


</CsScore>
</CsoundSynthesizer>

          

Credits

Author: John ffitch
University of Bath, Codemist. Ltd.
Bath, UK
December 2000

Example written by Kevin Conder.

New in Csound version 4.10